; -- OpenSecurity.iss --

 ; OpenSecurity setup file for use with

 ; Inno Setup Compiler (http://www.jrsoftware.org/isinfo.php) 

 ; Copyright 2013-2014 X-Net and AIT Austrian Institute of Technology

 ; 

 ; 

 ;     X-Net Services GmbH

 ;     Elisabethstrasse 1

 ;     4020 Linz

 ;     AUSTRIA

 ;     https://www.x-net.at

 ; 

 ;     AIT Austrian Institute of Technology

 ;     Donau City Strasse 1

 ;     1220 Wien

 ;     AUSTRIA

 ;     http://www.ait.ac.at

 ; 

 ; 

 ; Licensed under the Apache License, Version 2.0 (the "License");

 ; you may not use this file except in compliance with the License.

 ; You may obtain a copy of the License at

 ; 

 ;    http://www.apache.org/licenses/LICENSE-2.0

 ; 

 ; Unless required by applicable law or agreed to in writing, software

 ; distributed under the License is distributed on an "AS IS" BASIS,

 ; WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.

 ; See the License for the specific language governing permissions and

 ; limitations under the License.

 [Setup]

 AppName=OpenSecurity

 AppContact=AIT Austrian Institute of Technology

 AppPublisher=AIT Austrian Institute of Technology

 AppPublisherURL=http://www.ait.ac.at/

 AppVersion=1.0

 ArchitecturesInstallIn64BitMode=x64

 DefaultDirName={pf}\OpenSecurity

 DefaultGroupName=OpenSecurity

 ; DisableDirPage=yes

 ; DisableFinishedPage=yes

 ; DisableProgramGroupPage=yes

 ; DisableReadyMemo=yes

 ; DisableReadyPage=yes

 ; DisableWelcomePage=yes

 LicenseFile=OpenSecurity\Lizenz.txt

 OutputDir="."

 OutputBaseFilename="OpenSecurity Setup IKT V1.0"

 OutputManifestFile=OpenSecurity-Setup-Manifest.txt

 SetupIconFile=OpenSecurity\bin\ui\gfx\OpenSecurity.ico

 SolidCompression=yes

 UninstallDisplayIcon={app}\bin\ui\gfx\OpenSecurity.ico

 [Files]

 Source: "OpenSecurity\Lizenz.txt"; DestDir: "{app}"; 

 Source: "OpenSecurity\bin\*"; Excludes: "*.pyc,*.swp"; DestDir: "{app}\bin"; Flags: recursesubdirs createallsubdirs;

 Source: "OpenSecurity\cygwin64\*"; DestDir: "{app}\cygwin64"; Flags: recursesubdirs createallsubdirs;

 Source: "OpenSecurity\install\*"; DestDir: "{app}\install"; Flags: recursesubdirs createallsubdirs;

 Source: "OpenSecurity\python27\*"; DestDir: "{app}\python27"; Flags: recursesubdirs createallsubdirs;

 Source: "OpenSecurity\python27\python27.dll"; DestDir: "{sys}"; Flags: sharedfile;

 Source: "OpenSecurity\python27\Lib\site-packages\pywin32_system32\pywintypes27.dll"; DestDir: "{sys}"; Flags: sharedfile;

 Source: "OpenSecurity\systemprofile-IKT\.VirtualBox\*"; DestDir: "{sys}\config\systemprofile\.VirtualBox"; Flags: recursesubdirs createallsubdirs;

 Source: "OpenSecurity\systemprofile-IKT\VirtualBox VMs\*"; DestDir: "{sys}\config\systemprofile\VirtualBox VMs"; Flags: recursesubdirs createallsubdirs;

 Source: "OpenSecurity\Apache License, Version 2.0.txt"; DestDir: "{app}";

 [Dirs]

 Name: "{app}\cygwin64\var\log\xwin"; Permissions: everyone-modify

 Name: "{app}\log"; Permissions: everyone-modify

 [Registry]

 Root: HKLM; Subkey: "SOFTWARE\Microsoft\Windows\CurrentVersion\Run"; ValueName: "OpenSecurity Tray Icon"; ValueType: string; ValueData: "{app}\python27\pythonw.exe ""{app}\bin\opensecurity_tray.pyw"""; Flags: uninsdeletevalue

 Root: HKLM; Subkey: "SOFTWARE\OpenSecurity"; ValueName: "LogServerUrl"; ValueType: string; ValueData: "{code:URLLogServer}"; Flags: uninsdeletevalue

 Root: HKLM; Subkey: "SOFTWARE\OpenSecurity"; ValueName: "Browser"; ValueType: string; ValueData: "{code:VMBrowser}"; Flags: uninsdeletevalue

 Root: HKLM; Subkey: "SOFTWARE\OpenSecurity"; ValueName: "ImageUrl"; ValueType: string; ValueData: "http://service.x-net.at/opensecurity/OsecVM_latest.ova"; Flags: uninsdeletevalue

 Root: HKLM; Subkey: "SYSTEM\CurrentControlSet\services\USBSTOR"; ValueName: "Start"; ValueType: dword; ValueData: 4;

 [Icons]

 Name: "{group}\OpenSecurity Tray Icon"; Filename: "{app}\python27\pythonw.exe"; Parameters: """{app}\bin\opensecurity_tray.pyw"""; WorkingDir: "{userappdata}"; Comment: "The OpenSecurity Tray Icon"; IconFilename: "{app}\bin\ui\gfx\OpenSecurity.ico"

 Name: "{group}\Secure Browsing"; Filename: "{app}\cygiwn64\bin\wget.exe"; Parameters: """http://localhost:8080/browsing"""; WorkingDir: "{userappdata}"; Comment: "OpenSecurity Secure Browsing"; IconFilename: "{app}\bin\ui\gfx\opensecurity_browsing_64.ico"

 Name: "{commondesktop}\Secure Browsing"; Filename: "{app}\python27\pythonw.exe"; Parameters: """{app}\bin\start_browsing.pyw"""; WorkingDir: "{userappdata}"; Comment: "OpenSecurity Secure Browsing"; IconFilename: "{app}\bin\ui\gfx\opensecurity_browsing_64.ico"

 Name: "{group}\Uninstall OpenSecurity"; Filename: "{uninstallexe}"

 [Run]

 Filename: "{app}\cygwin64\bin\dash.exe"; Parameters: "/bin/rebaseall"; Description: "Rebasing background system"; WorkingDir: "{app}"; StatusMsg: "Rebasing background system..."; Flags: runascurrentuser

 Filename: "{app}\install\fix_cygwin_paths.bat"; Description: "Fixing Cygwin paths"; WorkingDir: "{app}\install"; StatusMsg: "Fixing Cygwin Paths...";

 Filename: "{app}\cygwin64\bin\bash.exe"; Parameters: "-l -i -c echo -n"; Description: "Enforcing login environment for shells"; WorkingDir: "{app}"; StatusMsg: "Enforcing login environment for shells...";

 Filename: "{app}\bin\firewall-install.bat"; Description: "Setup firewall rules"; WorkingDir: "{app}"; StatusMsg: "Setup firewall rules...";

 Filename: "{app}\python27\pythonw.exe"; Parameters: """{app}\bin\opensecurity_service.pyw"" --startup auto install"; Description: "Installing the OpenSecurity Service"; WorkingDir: "{app}"; StatusMsg: "Installing the OpenSecurity Service"; Flags: runascurrentuser

 Filename: "{app}\python27\pythonw.exe"; Parameters: """{app}\bin\opensecurity_service.pyw"" start"; Description: "Starting OpenSecurity Service"; WorkingDir: "{app}"; StatusMsg: "Starting OpenSecurity Service"; Flags: runascurrentuser

 Filename: "{app}\python27\pythonw.exe"; Parameters: """{app}\bin\opensecurity_tray.pyw"""; WorkingDir: "{userappdata}"; Description: "Launching OpenSecurity Tray Icon"; Flags: nowait

 [UninstallRun]

 Filename: "{app}\python27\pythonw.exe"; Parameters: """{app}\bin\terminate_client_tray.pyw"" stop"; WorkingDir: "{app}"; StatusMsg: "Stopping the OpenSecurity Client Tray Service"; Flags: runascurrentuser

 Filename: "{app}\python27\pythonw.exe"; Parameters: """{app}\bin\opensecurity_service.pyw"" stop"; WorkingDir: "{app}"; StatusMsg: "Stopping the OpenSecurity Service"; Flags: runascurrentuser

 Filename: "{app}\python27\pythonw.exe"; Parameters: """{app}\bin\opensecurity_service.pyw"" remove"; WorkingDir: "{app}"; StatusMsg: "Removing the OpenSecurity Service"; Flags: runascurrentuser

 Filename: "{app}\bin\firewall-uninstall.bat"; WorkingDir: "{app}"; StatusMsg: "Uninstall firewall rules...";

 [UninstallDelete]

 Type: filesandordirs; Name: "{app}"

 [Code]

 var

   UserInputPage: TInputQueryWizardPage;

 procedure InitializeWizard;

 begin

   // Create the page

   UserInputPage := CreateInputQueryPage(wpWelcome,

     'Installation Details', 

     'Essential settings for the current OpenSecurity Installation',

     'Please specify concrete details for the OpenSecurity Installation. In doubt, leave unchanged.');

   // Add items (False means it's not a password edit)

   UserInputPage.Add('VM Browser:', False);

   UserInputPage.Add('URL of Logserver:', False);

   // Set initial values (optional)

   UserInputPage.Values[0] := '/usr/bin/chromium';

   UserInputPage.Values[1] := 'http://10.215.5.166/opensecurity/log';

 end;

 function VMBrowser(Param: String): String;

 begin

   Result := UserInputPage.Values[0]

 end;

 function URLLogServer(Param: String): String;

 begin

   Result := UserInputPage.Values[1]

 end;