opensecurity: OpenSecurity.iss@cc8a15da3a13

     1 ; -- OpenSecurity.iss --

     2 ; OpenSecurity setup file for use with

     3 ; Inno Setup Compiler (http://www.jrsoftware.org/isinfo.php)

     5 [Setup]

     6 ; Basic installation stuff and config

     7 AppName=OpenSecurity

     8 AppContact=AIT Austrian Institute of Technology

     9 AppPublisher=AIT Austrian Institute of Technology

    10 AppPublisherURL=http://www.ait.ac.at/

    11 AppVersion=0.2.7

    12 ArchitecturesInstallIn64BitMode=x64

    13 DefaultDirName={pf}\OpenSecurity

    14 DefaultGroupName=OpenSecurity

    15 ; DisableDirPage=yes

    16 ; DisableFinishedPage=yes

    17 ; DisableProgramGroupPage=yes

    18 ; DisableReadyMemo=yes

    19 ; DisableReadyPage=yes

    20 ; DisableWelcomePage=yes

    21 OutputDir="."

    22 OutputBaseFilename="OpenSecurity Setup V0.2.7"

    23 OutputManifestFile=OpenSecurity-Setup-Manifest.txt

    24 SetupIconFile=OpenSecurity\bin\ui\gfx\OpenSecurity.ico

    25 SolidCompression=yes

    26 UninstallDisplayIcon={app}\bin\ui\gfx\OpenSecurity.ico

    28 [Files]

    29 ; Files to copy

    30 Source: "OpenSecurity\bin\*"; Excludes: "*.pyc,*.swp"; DestDir: "{app}\bin"; Flags: recursesubdirs createallsubdirs;

    31 Source: "OpenSecurity\cygwin64\*"; DestDir: "{app}\cygwin64"; Flags: recursesubdirs createallsubdirs;

    32 Source: "OpenSecurity\install\*"; DestDir: "{app}\install"; Flags: recursesubdirs createallsubdirs;

    33 Source: "OpenSecurity\python27\*"; DestDir: "{app}\python27"; Flags: recursesubdirs createallsubdirs;

    34 Source: "OpenSecurity\python27\python27.dll"; DestDir: "{sys}"; Flags: sharedfile;

    35 Source: "OpenSecurity\python27\Lib\site-packages\pywin32_system32\pywintypes27.dll"; DestDir: "{sys}"; Flags: sharedfile;

    36 Source: "OpenSecurity\systemprofile\.VirtualBox\*"; DestDir: "{sys}\config\systemprofile\.VirtualBox"; Flags: recursesubdirs createallsubdirs;

    37 Source: "OpenSecurity\systemprofile\VirtualBox VMs\*"; DestDir: "{sys}\config\systemprofile\VirtualBox VMs"; Flags: recursesubdirs createallsubdirs;

    38 Source: "OpenSecurity\Apache License, Version 2.0.txt"; DestDir: "{app}";

    40 [Dirs]

    41 Name: "{app}\cygwin64\var\log\xwin"; Permissions: everyone-modify

    42 Name: "{app}\log"; Permissions: everyone-modify

    44 [Registry]

    45 ; Registry entries to set

    46 Root: HKCU; Subkey: "SOFTWARE\Microsoft\Windows\CurrentVersion\Run"; ValueName: "OpenSecurity Tray Icon"; ValueType: string; ValueData: "{app}\python27\pythonw.exe ""{app}\bin\opensecurity_tray.pyw"""; Flags: uninsdeletevalue

    47 Root: HKLM; Subkey: "SOFTWARE\OpenSecurity"; ValueName: "LogServerUrl"; ValueType: string; ValueData: "http://extern.x-net.at/opensecurity/log"; Flags: uninsdeletevalue

    48 Root: HKLM; Subkey: "SYSTEM\CurrentControlSet\services\USBSTOR"; ValueName: "Start"; ValueType: dword; ValueData: 4;

    50 [Icons]

    51 ; Program Icons in start menu

    52 Name: "{group}\OpenSecurity Tray Icon"; Filename: "{app}\python27\pythonw.exe"; Parameters: """{app}\bin\opensecurity_tray.pyw"""; WorkingDir: "{userappdata}"; Comment: "The OpenSecurity Tray Icon"; IconFilename: "{app}\bin\ui\gfx\OpenSecurity.ico"

    53 Name: "{group}\Secure Browsing"; Filename: "{app}\cygiwn64\bin\wget.exe"; Parameters: """http://localhost:8080/browsing"""; WorkingDir: "{userappdata}"; Comment: "OpenSecurity Secure Browsing"; IconFilename: "{app}\bin\ui\gfx\opensecurity_browsing_64.ico"

    54 Name: "{commondesktop}\Secure Browsing"; Filename: "{app}\python27\pythonw.exe"; Parameters: """{app}\bin\start_browsing.pyw"""; WorkingDir: "{userappdata}"; Comment: "OpenSecurity Secure Browsing"; IconFilename: "{app}\bin\ui\gfx\opensecurity_browsing_64.ico"

    55 Name: "{group}\Uninstall OpenSecurity"; Filename: "{uninstallexe}"

    57 [Run]

    58 ; Run after installment

    59 Filename: "{app}\cygwin64\bin\dash.exe"; Parameters: "/bin/rebaseall"; Description: "Rebasing background system"; WorkingDir: "{app}"; StatusMsg: "Rebasing background system..."; Flags: runascurrentuser

    60 Filename: "{app}\install\fix_cygwin_paths.bat"; Description: "Fixing Cygwin paths"; WorkingDir: "{app}\install"; StatusMsg: "Fixing Cygwin Paths...";

    61 Filename: "{app}\cygwin64\bin\bash.exe"; Parameters: "-l -i -c echo -n"; Description: "Enforcing login environment for shells"; WorkingDir: "{app}"; StatusMsg: "Enforcing login environment for shells...";

    62 Filename: "{app}\python27\pythonw.exe"; Parameters: """{app}\bin\opensecurity_service.pyw"" --startup auto install"; Description: "Installing the OpenSecurity Service"; WorkingDir: "{app}"; StatusMsg: "Installing the OpenSecurity Service"; Flags: runascurrentuser

    63 Filename: "{app}\python27\pythonw.exe"; Parameters: """{app}\bin\opensecurity_service.pyw"" start"; Description: "Starting OpenSecurity Service"; WorkingDir: "{app}"; StatusMsg: "Starting OpenSecurity Service"; Flags: runascurrentuser

    64 Filename: "{app}\python27\pythonw.exe"; Parameters: """{app}\bin\opensecurity_tray.pyw"""; WorkingDir: "{userappdata}"; Description: "Launching OpenSecurity Tray Icon"; Flags: nowait

    66 [UninstallRun]

    67 ; When uninstalling run this command prior

    68 Filename: "{app}\python27\pythonw.exe"; Parameters: """{app}\bin\opensecurity_service.pyw"" stop"; WorkingDir: "{app}"; StatusMsg: "Stopping the OpenSecurity Service"; Flags: runascurrentuser

    69 Filename: "{app}\python27\pythonw.exe"; Parameters: """{app}\bin\opensecurity_service.pyw"" remove"; WorkingDir: "{app}"; StatusMsg: "Removing the OpenSecurity Service"; Flags: runascurrentuser

    71 [UninstallDelete]

    72 Type: filesandordirs; Name: "{app}"

author	Oliver Maurhart <oliver.maurhart@ait.ac.at>
	Thu, 26 Jun 2014 12:33:55 +0200
changeset 209	cc8a15da3a13
parent 186	e6c5d9ec9f6d
child 214	2e2261ce334b
permissions	-rw-r--r--